ライフハック

2024/08/25

引き出し日記のアプリで書いていたメモをNotionに移行した話

こんにちは。那須野です。

今回は、引き出し日記という「簡単に呟きをプライベートに記録して後から簡単に検索できる日記アプリ」で今まで書いてきた呟きメモを、Notionに移行したときの作業の流れを、備忘録としてまとめます。

引き出し日記を使っていた理由

引き出し日記は、iOSやAndroidで使える日記アプリです。

X（旧Twitter）みたいな感じに簡単に呟くことができて、それを高速に検索できるアプリです。無料でも十分に使うことができて、いつ何をやったかの記録を取っていました。とりわけ

いつか行ったあの場所はいつ行ったっけ…？
習慣的な行動をどれくらいのペースでやっていたっけ？

みたいなものを検索して調べるのに便利で使っていました。データは端末自体に保存されるので、PCやブラウザで見ることはできませんが、代わりにとにかく高速で検索できるところがポイントです。無料の範囲内で十分に使えるのもポイントが高いです。

なお、X（旧Twitter）との違いは、完全にプライベートであること。自分しか見られないので、家庭のことでも何でも自由に書くことができます。ちなみに画像もアップロードできるのですが、私はテキスト一辺倒で使っていました。

Notionに移行することにした理由

引き出し日記自体に不満があったわけではないのですが、今回はNotionに移行しようという決断をしました。問題は、プライベートの情報が散らばりすぎていたことです。

具体的にどうなっていたかというと、タスク管理はAsana、カレンダーはYahooカレンダー、フロー的な情報管理は引き出し日記、ストック的な情報管理はNotionやGoogleスプレッドシートなどと色々なアプリを使っていたのです。

そういった状態の中、過去に何をやったか調べようとするとまず引き出し日記で検索してみるのですが、引き出し日記に何でもかんでも網羅的に入力しているわけではなく、ちょっとしたTODOや予定的なものはAsanaやYahoo!カレンダーにだけ入っていることが多いため、引き出し日記を検索しても出てこない。「あれ、どのアプリで入れてたっけな…？」となります。

引き出し日記は2年ほど使っており、それくらい長い期間になってくると、昔のことをどのアプリに入力していたかパッと思い出せないことが増えてきます。2年でコレなので、これ以上この状況を続けていたら今よりもっと不便な未来がやってくることは想像に難くありませんでした。

なるべく一つにまとめたいと考えたときに、選択肢として挙がったのがNotionでした。すでにストック的な情報をまとめるのには使っていましたし、ビジネス用途ではあらゆる情報をNotionに集約する使い方が色々あるのは分かっていたので、これならイケるだろう、と。

引き出し日記からNotionにデータ移行する作業の流れ

Notionは自由にデータベースを作れるので、日記用にデータベースを作ります。引き出し日記から移行したいデータの形式は

本文（名前）※文字列型
日時　※日付型

の2カラムでよいので、この2カラム＋αでデータベースを作っておきます。その後、引き出し日記からデータをエクスポートし、データを成形してCSVファイルとして保存したうえで、Notionにインポートすれば移行完了になります。

それではステップごとに見ていきましょう。

①引き出し日記からエクスポート

引き出し日記のデータを出力するにはテキストでのバックアップ機能が必要ですが、実はこれはプレミアムプランが必要になります。

なお、2024年8月現在、プレミアムプランは最初の7日間が無料なので、もしプレミアムプランを利用していない場合は、移行するためにプレミアムプランを購入し、作業が終わったら課金される前に可及的速やかに解約すれば大丈夫です。

さて、テキストファイルとしてエクスポートしたファイルは、以下のような形式でした…。

2024-08-17
10:19 ＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊

＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
13:18 ＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
13:22 ＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
23:25 ＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊

2024-08-18
12:01 ＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
18:45 ＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊

もちろん実際の呟きはアスタリスクで隠していますが、ここから分かることとしては、

CSVなどテーブル構造ではない。
yyyy-mm-ddの日付行から始まる。
hh:mmから1つの呟きが始まり、半角スペースを挟んで実際の呟きの文章が続く。
呟きの文章に改行がある場合、改行されたまま出力される。
日付が変わる場合は空白行が入る。

CSVファイルであればExcelで手作業で加工することもできましたが、こうなると簡単には加工できません。2年分と量も多いので、もちろん手動でやるなど考えられません。しょうがないので、Excel VBAでデータを成型するコードを書いて処理することにしました。

②Excelファイル化

Excel VBAで処理できるようにするために、Excelファイルを開き、Sheet1のA列のセルの表示形式を「文字列」に変換したうえで、テキストファイルの値をA列にそのまま貼り付けます。

ちなみに「文字列」に変換しておくのは、日付テキストしかない日付行が勝手に日付型として認識されて値変換されるのを防ぐためです。

③Excel VBAを実行してデータを成形

以下のようなコードを書いて、さっそく実行しましょう。成形されたデータが新しいシートとして生成されます。

Option Explicit

Sub convertData()

    Dim inputSheet As Worksheet, inputCells As Range, inputText As String, inputRow As Long
    Dim outputSheet As Worksheet, outputCells As Range, outputRow As Long, outputDate As String, outputTime As String, outputText As String, tempOutputText As String
    Dim blankRowCount As Long, maxBlankRowCount As Long
    
    'インプットの定義
    Set inputSheet = Worksheets("Sheet1")
    Set inputCells = inputSheet.Cells
    
    'アウトプットの定義
    Set outputSheet = ActiveWorkbook.Worksheets.Add
    Set outputCells = outputSheet.Cells
    
    'アウトプットシートのヘッダー定義
    Range(outputCells(1, 1), outputCells(1, 2)).Value = Array("名前", "日付")
        
    '日付行を検出する正規表現
    Dim isDateRow As Object
    Set isDateRow = CreateObject("VBScript.RegExp")
    isDateRow.Pattern = "^20\d\d-\d\d-\d\d$"
    
    '時間行を検出する正規表現
    Dim isTimeRow As Object
    Set isTimeRow = CreateObject("VBScript.RegExp")
    isTimeRow.Pattern = "^(\d\d:\d\d )"
    
    'インプットシートを上から走査してアウトプットシートに転記する。空白行が5行を超えたら終了とする
    inputRow = 1
    outputRow = 1
    blankRowCount = 0
    maxBlankRowCount = 5
    Do
        inputText = inputCells(inputRow, 1).Value
        
        '日付行なのでinsert確認したうえで、初期化しつつ日付だけセット
        If isDateRow.test(inputText) Then
            Call checkAndInsertRecord(outputDate, outputTime, outputText, outputCells, outputRow)
        
            outputDate = Format(CDate(inputText), "yyyy年m月d日") 'yyyy年m月d日で出力
            outputTime = ""
            outputText = ""
            blankRowCount = 0
            
        '時間行なのでinsert確認したうえで、時間とテキストをセット
        ElseIf isTimeRow.test(inputText) Then
            Call checkAndInsertRecord(outputDate, outputTime, outputText, outputCells, outputRow)
            
            outputTime = IIf(Left(inputText, 1) = "0", Mid(inputText, 2, 4), Left(inputText, 5)) 'h:nnで出力
            outputText = Mid(inputText, 7, 9999)
            blankRowCount = 0
        
        '空白行なので、スキップする
        ElseIf inputText = "" Then
            blankRowCount = blankRowCount + 1
        
        '改行後に続くoutputTextなので、直前の空白行を意識しつつテキストに足す
        Else
            outputText = outputText & repeatString(vbNewLine, blankRowCount + 1) & inputText
            blankRowCount = 0
        End If
        
        If blankRowCount > maxBlankRowCount Then
            Call checkAndInsertRecord(outputDate, outputTime, outputText, outputCells, outputRow)
            Exit Do
        End If
        
        inputRow = inputRow + 1
    Loop
    
    MsgBox "Finished with " & (outputRow - 1) & " output rows!"

End Sub

'レコードを出力できるか確認のうえ、できるならそのまま出力する関数
Sub checkAndInsertRecord(ByVal outputDate As String, ByVal outputTime As String, ByVal outputText As String, ByRef outputCells As Range, ByRef outputRow As Long)
    If outputDate <> "" And outputTime <> "" And outputText <> "" Then
        outputRow = outputRow + 1
        Range(outputCells(outputRow, 1), outputCells(outputRow, 2)).Value = Array(outputText, outputDate & " " & outputTime)
    End If
End Sub

'文字列を指定個数だけ並べて返す関数
Function repeatString(ByVal str As String, ByVal n As Long) As String
    Dim result As String, i As Long
    result = ""
    For i = 1 To n
        result = result & str
    Next i
    repeatString = result
End Function

Option Explicit

Sub convertData()

Dim inputSheet As Worksheet, inputCells As Range, inputText As String, inputRow As Long

Dim outputSheet As Worksheet, outputCells As Range, outputRow As Long, outputDate As String, outputTime As String, outputText As String, tempOutputText As String

Dim blankRowCount As Long, maxBlankRowCount As Long

'インプットの定義

Set inputSheet = Worksheets("Sheet1")

Set inputCells = inputSheet.Cells

'アウトプットの定義

Set outputSheet = ActiveWorkbook.Worksheets.Add

Set outputCells = outputSheet.Cells

'アウトプットシートのヘッダー定義

Range(outputCells(1, 1), outputCells(1, 2)).Value = Array("名前", "日付")

'日付行を検出する正規表現

Dim isDateRow As Object

Set isDateRow = CreateObject("VBScript.RegExp")

isDateRow.Pattern = "^20\d\d-\d\d-\d\d$"

'時間行を検出する正規表現

Dim isTimeRow As Object

Set isTimeRow = CreateObject("VBScript.RegExp")

isTimeRow.Pattern = "^(\d\d:\d\d )"

'インプットシートを上から走査してアウトプットシートに転記する。空白行が5行を超えたら終了とする

inputRow = 1

outputRow = 1

blankRowCount = 0

maxBlankRowCount = 5

inputText = inputCells(inputRow, 1).Value

'日付行なのでinsert確認したうえで、初期化しつつ日付だけセット

If isDateRow.test(inputText) Then

Call checkAndInsertRecord(outputDate, outputTime, outputText, outputCells, outputRow)

outputDate = Format(CDate(inputText), "yyyy年m月d日") 'yyyy年m月d日で出力

outputTime = ""

outputText = ""

blankRowCount = 0

'時間行なのでinsert確認したうえで、時間とテキストをセット

ElseIf isTimeRow.test(inputText) Then

Call checkAndInsertRecord(outputDate, outputTime, outputText, outputCells, outputRow)

outputTime = IIf(Left(inputText, 1) = "0", Mid(inputText, 2, 4), Left(inputText, 5)) 'h:nnで出力

outputText = Mid(inputText, 7, 9999)

blankRowCount = 0

'空白行なので、スキップする

ElseIf inputText = "" Then

blankRowCount = blankRowCount + 1

'改行後に続くoutputTextなので、直前の空白行を意識しつつテキストに足す

Else

outputText = outputText & repeatString(vbNewLine, blankRowCount + 1) & inputText

blankRowCount = 0

End If

If blankRowCount > maxBlankRowCount Then

Call checkAndInsertRecord(outputDate, outputTime, outputText, outputCells, outputRow)

Exit Do

End If

inputRow = inputRow + 1

Loop

MsgBox "Finished with " & (outputRow - 1) & " output rows!"

End Sub

'レコードを出力できるか確認のうえ、できるならそのまま出力する関数

Sub checkAndInsertRecord(ByVal outputDate As String, ByVal outputTime As String, ByVal outputText As String, ByRef outputCells As Range, ByRef outputRow As Long)